VBA と Java のオブジェクト指向プログラミング

VBADP03編集する

最終更新： donkichi donkichi 2009年12月05日(土) 16:13:15履歴

Top > Excel VBA でデザインパターン > TemplateMethodパターン

TemplateMethodパターン


TemplateMethodパターンのサンプルプログラムをExcelVBAで記述すると以下の
ようになります。モジュールごとにプログラムを示します。

標準モジュール：modCObject
'=================================================>>>>>>>>>>
'標準モジュール：modCObject
'===========================================================
Option Explicit

'コンストラクタ
Public Function Init2(pobjConcrete As clsCObject _
) As clsCObject
    Dim objResult As clsCObject
    Set objResult = New clsCObject
    '抽象メソッドの実際の処理が記述されている
    'サブクラスのインスタンスを引数で渡す。
    Call objResult.Init2(pobjConcrete)
    Set Init2 = objResult
End Function
'<<<<<<<<<<=================================================
クラスモジュール：clsCObject
'=================================================>>>>>>>>>>
'クラスモジュール：clsCObject
'===========================================================
'抽象メソッドの実際の処理が記述されている
'サブクラスのインスタンスを取得するために
'使用するスーパークラス。
Option Explicit
'抽象メソッドの実際の処理が記述されている
'サブクラスのインスタンス。
Private mobjConcrete As clsCObject

'コンストラクタ
'抽象メソッドの実際の処理が記述されている
'サブクラスのインスタンスを引数で受け取る。
Public Sub Init2(pobjConcrete As clsCObject)
    Set mobjConcrete = pobjConcrete
End Sub

'抽象メソッドの実際の処理が記述されている
'サブクラスのインスタンスの取得処理。
Public Property Get Concrete() As clsCObject
    Set Concrete = mobjConcrete
End Property
'<<<<<<<<<<=================================================
標準モジュール：modCAbstractDisplay
'=================================================>>>>>>>>>>
'標準モジュール：modCAbstractDisplay
'===========================================================
Option Explicit

'コンストラクタ
Public Function Init2(pobjConcrete As clsCObject _
) As clsCAbstractDisplay
    Dim objResult As clsCAbstractDisplay
    Set objResult = New clsCAbstractDisplay
    '抽象メソッドの実際の処理が記述されている
    'サブクラスのインスタンスを引数で渡す。
    Call objResult.Init2(pobjConcrete)
    Set Init2 = objResult
End Function
'<<<<<<<<<<=================================================
クラスモジュール：clsCAbstractDisplay
'=================================================>>>>>>>>>>
'クラスモジュール：clsCAbstractDisplay
'===========================================================
Option Explicit
'スーパークラス情報
Implements clsCObject
Private mobjSuper As clsCObject
'コンストラクタ
Public Sub Init2(pobjConcrete As clsCObject)
    'スーパークラスのコンストラクタを呼び出す。
    '抽象メソッドの実際の処理が記述されている
    'サブクラスのインスタンスを引数で渡す。
    Set mobjSuper = modCObject.Init2(pobjConcrete)
End Sub

'Concreteプロパティは継承を実現する
'内部処理用のプロパティであり
'クラスの利用者に見せる必要がないため
'継承しているように見せかける
'Publicプロシージャは定義しない。

'サブクラスに実装をまかせる抽象メソッド(1)
'「Open」はVBAの予約語でプロシージャ名に使えないので
'「OpenDisp」にする。
Public Sub OpenDisp()
'
End Sub

'サブクラスに実装をまかせる抽象メソッド(2)
'「Print」はVBAの予約語でプロシージャ名に使えないので
'「PrintDisp」にする。
Public Sub PrintDisp()
'
End Sub

'サブクラスに実装をまかせる抽象メソッド(3)
'「Close」はVBAの予約語でプロシージャ名に使えないので
'「CloseDisp」にする。
Public Sub CloseDisp()
'
End Sub

'スーパークラスから抽象メソッドの実際の処理が
'記述されているサブクラスのインスタンスを取得する。
Public Sub Display()
    '抽象メソッドの実際の処理が記述されている
    'サブクラスのインスタンスを設定する変数。
    'データ型は自分自身にする。
    Dim objConcrete As clsCAbstractDisplay
    Dim lngCnt As Long
    Set objConcrete = clsCObject_Concrete
    'まずOpenして…
    Call objConcrete.OpenDisp
    '5回Printを繰り返して…
    For lngCnt = 1 To 5
        Call objConcrete.PrintDisp
    Next lngCnt
    '…最後にCloseする。
    Call objConcrete.CloseDisp
End Sub

'-----------------------------------------------------------
' clsCObject のインターフェイス
'-----------------------------------------------------------
Private Sub clsCObject_Init2(pobjConcrete As clsCObject)
    '何もしない
End Sub

Private Property Get clsCObject_Concrete() As clsCObject
    Set clsCObject_Concrete = mobjSuper.Concrete
End Property
'<<<<<<<<<<=================================================
標準モジュール：modCCharDisplay
'=================================================>>>>>>>>>>
'標準モジュール：modCCharDisplay
'===========================================================
Option Explicit

'コンストラクタ２
Public Function Init2(pstrCh As String) As clsCCharDisplay
    Dim objResult As clsCCharDisplay
    Set objResult = New clsCCharDisplay
    Call objResult.Init2(pstrCh)
    Set Init2 = objResult
End Function
'<<<<<<<<<<=================================================
クラスモジュール：clsCCharDisplay
'=================================================>>>>>>>>>>
'クラスモジュール：clsCCharDisplay
'===========================================================
Option Explicit
'スーパークラス情報
'clsCCharDisplay は、clsCAbstractDisplay のサブクラス。
Implements clsCObject
Implements clsCAbstractDisplay
Private mobjSuper As clsCAbstractDisplay
'プロパティ情報
'表示すべき文字
Private mstrCh As String

'コンストラクタ
Public Function Init2(pstrCh As String) As clsCCharDisplay
    'スーパークラスのコンストラクタの呼び出し
    '抽象メソッドの実際の処理が記述されている
    'サブクラスのインスタンスを引数で渡す。
    Set mobjSuper = modCAbstractDisplay.Init2(Me)
    'コンストラクタで渡された文字 pstrCh を、
    'プロパティに記憶しておく。
    'VBA に char 型はないので、String 型のデータの
    '先頭１文字を取り出す。
    mstrCh = Left(pstrCh, 1)
End Function

'Concreteプロパティは継承を実現する
'内部処理用のプロパティであり
'クラスの利用者に見せる必要がないため
'継承しているように見せかける
'Publicプロシージャは定義しない。

'-----------------------------------------------------------
'clsCAbstractDisplay で定義されているメソッドを
'clsCCharDisplay 型の変数からも呼び出せるようにする。
'-----------------------------------------------------------
'スーパークラスでは抽象メソッドだった。
'ここでオーバーライドして実装。
'開始文字列として"<<"を表示する。
Public Sub OpenDisp()
    Debug.Print "<<";
End Sub

'print メソッドもここで実装する。これが display から繰り返して呼び出される。
'プロパティに記憶しておいた文字を1個表示する。
Public Sub PrintDisp()
    Debug.Print mstrCh;
End Sub

'close メソッドもここで実装。
'終了文字列">>"を表示。
Public Sub CloseDisp()
    Debug.Print ">>"
End Sub

Public Sub Display()
    Call mobjSuper.Display
End Sub

'-----------------------------------------------------------
' clsCAbstractDisplay のインターフェイス
'-----------------------------------------------------------
Private Sub clsCAbstractDisplay_Init2( _
pobjConcrete As clsCObject)
    '何もしない
End Sub

Private Sub clsCAbstractDisplay_OpenDisp()
    Call Me.OpenDisp
End Sub

Private Sub clsCAbstractDisplay_PrintDisp()
    Call Me.PrintDisp
End Sub

Private Sub clsCAbstractDisplay_CloseDisp()
    Call Me.CloseDisp
End Sub

Private Sub clsCAbstractDisplay_Display()
    Call Me.Display
End Sub

'-----------------------------------------------------------
' clsCObject のインターフェイス
'-----------------------------------------------------------
Private Sub clsCObject_Init2(pobjConcrete As clsCObject)
    '何もしない
End Sub

Private Property Get clsCObject_Concrete() As clsCObject
    Dim obj As clsCObject
    Set obj = mobjSuper
    Set clsCObject_Concrete = obj.Concrete
End Property
'<<<<<<<<<<=================================================
標準モジュール：modCStringDisplay
'=================================================>>>>>>>>>>
'標準モジュール：modCStringDisplay
'===========================================================
Option Explicit
'コンストラクタ２
Public Function Init2(pstrValue As String _
) As clsCStringDisplay
    Dim objResult As clsCStringDisplay
    Set objResult = New clsCStringDisplay
    objResult.Init2 pstrValue
    Set Init2 = objResult
End Function
'<<<<<<<<<<=================================================
クラスモジュール：clsCStringDisplay
'=================================================>>>>>>>>>>
'クラスモジュール：clsCStringDisplay
'===========================================================
Option Explicit
'スーパークラスの情報
'StringDisplayも、AbstractDisplayのサブクラス。
Implements clsCObject
Implements clsCAbstractDisplay
Private mobjSuper As clsCAbstractDisplay
'プロパティ情報
'表示するべき文字列。
Private mstrValue As String
'バイト単位で計算した文字列の「幅」。
Private mlngWidth As Long

'コンストラクタ
Public Function Init2(pstrValue As String _
) As clsCStringDisplay
    'スーパークラスのコンストラクタの呼び出し。
    '抽象メソッドの実際の処理が記述されている
    'サブクラスのインスタンスを引数で渡す。
    Set mobjSuper = modCAbstractDisplay.Init2(Me)
    'コンストラクタで渡された文字 pstrValue を、
    'プロパティに記憶。
    mstrValue = pstrValue
    'それからバイト単位の幅もフィールドに
    '記憶しておいて、後で使う。
    mlngWidth = LenB(StrConv(mstrValue, vbFromUnicode))
End Function

'Concreteプロパティは継承を実現する
'内部処理用のプロパティであり
'クラスの利用者に見せる必要がないため
'継承しているように見せかける
'Publicプロシージャは定義しない。

'-----------------------------------------------------------
'clsCAbstractDisplay で定義されているメソッドを
'clsCStringDisplay 型の変数からも呼び出せるようにする。
'-----------------------------------------------------------
'オーバーライドして定義する openDisp メソッド。
'このクラスのメソッド printLine で線を引いている。
Public Sub OpenDisp()
    Call PrintLine
End Sub

'printDisp メソッドは、プロパティに記憶しておいた文字列
'の前後に"|"をつけて表示。
Public Sub PrintDisp()
    Debug.Print "|" & mstrValue & "|"
End Sub

'closeDsipメソッドは、openと同じくprintLineメソッドで
'線を引いている｡
Public Sub CloseDisp()
    Call PrintLine
End Sub

Public Sub Display()
    mobjSuper.Display
End Sub

'OpenDisp と CloseDisp から呼ばれる PrintLine メソッドだ。
'Private なので、このクラスの中だけで使われる。
Private Sub PrintLine()
    Dim lngCnt As Long
    '枠の角を表現する"+"マークを表示。
    Debug.Print "+";
    'width個の"-"を表示して、枠線として用いる
    For lngCnt = 1 To mlngWidth
        Debug.Print "-";
    Next lngCnt
    '枠の角を表現する"+"マークを表示。
    Debug.Print "+"
End Sub

'-----------------------------------------------------------
' clsCAbstractDisplay のインターフェイス
'-----------------------------------------------------------
Private Sub clsCAbstractDisplay_Init2( _
pobjConcrete As clsCObject)
    '何もしない
End Sub

Private Sub clsCAbstractDisplay_OpenDisp()
    Call Me.OpenDisp
End Sub

Private Sub clsCAbstractDisplay_PrintDisp()
    Call Me.PrintDisp
End Sub

Private Sub clsCAbstractDisplay_CloseDisp()
    Call Me.CloseDisp
End Sub

Private Sub clsCAbstractDisplay_Display()
    Call Me.Display
End Sub

'-----------------------------------------------------------
' clsCObject のインターフェイス
'-----------------------------------------------------------
Private Sub clsCObject_Init2(pobjConcrete As clsCObject)
    '何もしない
End Sub

Private Property Get clsCObject_Concrete() As clsCObject
    Dim obj As clsCObject
    Set obj = mobjSuper
    Set clsCObject_Concrete = obj.Concrete
End Property
'<<<<<<<<<<=================================================
標準モジュール：modCMain
'=================================================>>>>>>>>>>
'標準モジュール：modCMain
'===========================================================
Option Explicit

'メイン処理１
Sub Main1()
    Dim d1 As clsCAbstractDisplay
    Dim d2 As clsCAbstractDisplay
    Dim d3 As clsCAbstractDisplay
    '"H"を持ったclsCCharDisplayのインスタンスを1個作る。
    Set d1 = modCCharDisplay.Init2("H")
    '"Hello, world."を持ったclsCStringDisplay
    'のインスタンスを1個作る。
    Set d2 = modCStringDisplay.Init2("Hello, world.")
    '"こんにちは。"を持ったclsCStringDisplay
    'のインスタンスを1個作る。
    Set d3 = modCStringDisplay.Init2("こんにちは。")
    'd1,d2,d3とも、すべて同じclsCAbstractDisplay
    'のサブクラス 'のインスタンスだから、
    '継承したDisplayメソッドを呼び出すことができる。
    '実際の動作は個々のクラスclsCCharDisplayや
    'clsCStringDisplayで定まる。
    Call d1.Display
    Call d2.Display
    Call d3.Display
End Sub
'<<<<<<<<<<=================================================

Top > Excel VBA でデザインパターン > TemplateMethodパターン
このエントリーをTumblrにポストClip to Evernoteこのエントリーをはてなブックマークに追加
VBADP03 - VBA と Java のオブジェクト指向プログラミング 先頭へ

このページへのコメント

4UPuVd I really like and appreciate your article.Thanks Again. Great.

0
Posted by seo thing 2013年12月20日(金) 22:10:44 返信

VBADP03 - VBA 鐃緒申 Java 鐃塾ワ申鐃瞬ワ申鐃緒申鐃緒申鐃夙指醐申鐃竣ワ申鐃緒申鐃淳ワ申 - Seesaa Wiki鐃淑ワ申鐃緒申鐃緒申鐃緒申 for 鐃緒申鐃殉￥申鐃夙フワ申鐃緒申 ��≪�潟�������若�� ��������潟�純�� ��≪�������������� http://www.pslcbi.com/moncler2014.html

0
Posted by ��≪�潟�������若�� ��������潟�純�� ��≪�������������� 2013年12月10日(火) 10:21:48 返信

VBADP03 - VBA 鐃緒申 Java 鐃塾ワ申鐃瞬ワ申鐃緒申鐃緒申鐃夙指醐申鐃竣ワ申鐃緒申鐃淳ワ申 - Seesaa Wiki鐃淑ワ申鐃緒申鐃緒申鐃緒申 for 鐃緒申鐃殉￥申鐃夙フワ申鐃緒申 ��≪�潟�������若�� 綺���� http://www.pslcbi.com/moncler2014.html

0
Posted by ��≪�潟�������若�� 綺���� 2013年12月07日(土) 15:12:31 返信

pycGzJ <a href="http://baykqjhqgqjv.com/">baykqjhqgqjv</a>, [url=http://vuprazkbdpqn.com/]vuprazkbdpqn[/url], [link=http://hjiwrgdjxcld.com/]hjiwrgdjxcld[/link], http://ybbajflkyugm.com/

0
Posted by qlojkt 2013年11月15日(金) 05:38:04 返信

コメントをかく


「http://」を含む投稿は禁止されています。

利用規約をご確認のうえご記入下さい
 

サイト構成

トップページ
├オブジェクト指向プログラミング
├VBA のオブジェクト指向プログラミング
├VBA のプログラムを Java のプログラムに移植する方法
├Java のプログラムを VBA のプログラムに移植する方法
└Excel VBA でデザインパターン
　└Iterator パターン
　└Adapter パターン（継承）
　└Adapter パターン（委譲）
　└TemplateMethod パターン
　└FactoryMethod パターン
　└Singleton パターン
　└Prototype パターン

カテゴリー

最近更新したページ

最新コメント

編集にはIDが必要です