smnb

• Ensure that exp is non-zero. If it is zero, then exit the linker with an error code, and print message.

#top

Entry point is he first instruction to execute in a program.
To set the entry point:

• the ‘-e’ entry command-line option;
• the ENTRY(symbol) command in a linker script;
• the value of the symbol start, if defined;
• the address of the first byte of the ‘.text’ section, if present;
• The address 0.

#top

• Force symbol to be entered in the output file as an undefined symbol.
• Doing this may, for example, trigger linking of additional modules from standard libraries.
• You may list several symbols for each EXTERN, and you may use EXTERN multiple times.
• This command has the same effect as the ‘-u’ command-line option.

#top

• This command has the same effect as the ‘-d’ command-line option: to make ld assign space to common symbols even if a relocatable output file is specified (‘-r’).

#top

or GROUP(file file ...)
The GROUP command is like INPUT, except that the named files should all be archives, and they are searched repeatedly until no new undefined references
are created.
#top

• Include the linker script filename at this point.
• The file will be searched for in the current directory, and in any directory specified with the ‘-L’ option.
• Nest calls to INCLUDE up to 10 levels deep.

#top

• This command has the same effect as the ‘--no-define-common’ command-line option: to make ld omit the assignment of addresses to common symbols even for a non-relocatable output file.

#top

or INPUT(file file ...)

• The INPUT command directs the linker to include the named files in the link, as though they were named on the command line.
  • use INPUT (subr.o) in script instead of listing subr.o in command line.
• In case a sysroot prefix is configured, and the filename starts with the ‘/’character, and the script being processed was located inside the sysroot prefix, the filename will be looked for in the sysroot prefix. Otherwise, the linker will try to open the file in the current directory. If it is not found, the linker will

search through the archive library search path.

• Use ‘INPUT (-lfile)’for libfile.a.

#top

• This command may be used to tell ld to issue an error about any references among certain output sections.
• In certain types of programs, particularly on embedded systems when using overlays, when one section is loaded into memory, another section will not be.
• Any direct references between the two sections would be errors.
• For example, it would be an error if code in one section called a function defined in the other section.
• The NOCROSSREFS command takes a list of output section names.
• If ld detects any cross references between the sections, it reports an error and returns a non-zero exit status.
• Note that the NOCROSSREFS command uses output section names, not input section names.

#top

• Using OUTPUT(filename) in the linker script is exactly like using ‘-o filename’ on the command line.
• If both are used, the command line option takes precedence.
• Use the OUTPUT command to define a default name for the output file other than the usual default of ‘a.out’.

#top

• Specify a particular output machine architecture.
• The argument is one of the names used by the BFD library.
• You can see the architecture of an object file by using the objdump program with the ‘-f’option.

i386

arm

v850

#top

or OUTPUT_FORMAT(default, big, little)

• The OUTPUT_FORMAT command names the BFD format to use for the output file.
  • Using OUTPUT_FORMAT(bfdname) is exactly like using ‘--oformat bfdname’ on the command line.
  • If both are used, the command line option takes precedence.
• You can use OUTPUT_FORMAT with three arguments to use different formats based on the ‘-EB’ and ‘-EL’ command line options.
  • This permits the linker script to set the output format based on the desired endianness.
  • If neither ‘-EB’ nor ‘-EL’ are used, then the output format will be the first argument, default.
  • If ‘-EB’ is used, the output format will be the second argument, big.
  • If ‘-EL’ is used, the output format will be the third argument, little.
  • For example, the default linker script for the MIPS ELF target uses this command:

OUTPUT_FORMAT(elf32-bigmips, elf32-bigmips, elf32-littlemips)

This says that the default format for the output file is ‘elf32-bigmips’, but if the user uses the ‘-EL’ command line option, the output file will be created in the ‘elf32-littlemips’ format.

binary	This is just a flat binary with no formatting at all
elf32-i386	This is just the ELF format, usually little endian too.
elf64-x86-64	This is the ELF format for 64bit, usually little endian.
pe-i386	The PE format
elf32-littlearm
elf32-bigarm
elf32-v850

• Using SEARCH_DIR(path) is exactly like using ‘-L path’ on the command line.
• If both are used, then the linker will search both paths.
• Paths specified using the command line option are searched first.

#top

• The STARTUP command is just like the INPUT command, except that filename will become the first input file to be linked, as though it were specified first on the command line.
• This may be useful when using a system in which the entry point is always the start of the first file.

• The TARGET command names the BFD format to use when reading input files.
• It affects subsequent INPUT and GROUP commands.
• This command is like using ‘-b bfdname’ on the command line
• If the TARGET command is used but OUTPUT_FORMAT is not, then the last TARGET command is also used to set the format for the output file.

#top

• The SECTIONS command tells the linker how to map input sections into output sections, and how to place the output sections in memory.

SECTIONS
{
    sections-command
    sections-command
    ...
}

• Each sections-command may of be one of the following:
  • an ENTRY command
  • a symbol assignment
  • an output section description
  • an overlay description
• The ENTRY command and symbol assignments are permitted inside the SECTIONS command for convenience in using the location counter in those commands.

#top #sections

The full description of an output section looks like this:

section [address] [(type)] : [AT(lma)]
{
    output-section-command
    output-section-command
    ...
} [>region] [AT>lma_region] [:phdr :phdr ...] [=fillexp]

• The whitespace around section is required, so that the section name is unambiguous.
• The colon and the curly braces are also required.
• The line breaks and other white space are optional.
• Each output-section-command may be one of the following:
  • a symbol assignment
  • an input section description
  • data values to include directly
  • a special output section keyword

• The name of the output section is section. section must meet the constraints of the output format.
• In formats which only support a limited number of sections, such as a.out, the name must be one of the names supported by the format.
  • a.out, for example, allows only ‘.text’, ‘.data’ or ‘.bss’.
• If the output format supports any number of sections, but with numbers and not names (as is the case for Oasys), the name should be supplied as a quoted numeric string.
• A section name may consist of any sequence of characters, but a name which contains any unusual characters such as commas must be quoted.
• The output section name ‘/DISCARD/’ is special.

#top #sections

• The address is an expression for the VMA (the virtual memory address) of the output section.
• If you do not provide address, the linker will set it based on region if present, or otherwise based on the current value of the location counter.
• If you provide address, the address of the output section will be set to precisely that.
• If you provide neither address nor region, then the address of the output section will be set to the current value of the location counter aligned to the alignment requirements of the output section.
• The alignment requirement of the output section is the strictest alignment of any input section contained within the output section.
  • For example,

.text . : { *(.text) } /* set the address of the ‘.text’ output section to the current value of the location counter. */
---
.text : { *(.text) } /* set the address to the current value of the location counter aligned to the strictest alignment of a ‘.text’ input section. */

• The address may be an arbitrary expression.
  • For example, if you want to align the section on a 0x10 byte boundary, so that the lowest four bits of the section address are zero, you could do something like this:

.text ALIGN(0x10) : { *(.text) }

• This works because ALIGN returns the current location counter aligned upward to the specified value.
• Specifying address for a section will change the value of the location counter.

#top #sections

• Use input section descriptions to tell the linker how to map the input files into the memory layout.

#top #sections

• An input section description consists of a file name optionally followed by a list of section names in parentheses.
• The file name and the section name may be wildcard patterns.
• The most common input section description is to include all input sections with a particular name in the output section.
  • For example, to include all input ‘.text’ sections:

*(.text)   /* Here the ‘*’ is a wildcard which matches any file name. */
(*(EXCLUDE_FILE (*crtend.o *otherfile.o) .ctors))  /* all .ctors sections from all files except ‘crtend.o’ and ‘otherfile.o’ to be included. */

• To include more than one section:

*(.text .rdata)   /* the ‘.text’ and ‘.rdata’ input sections will be intermingled, appearing in the same order as they are found in the linker input. */
/* -- or -- */
*(.text) *(.rdata)  /* all ‘.text’input sections will appear first, followed by all ‘.rdata’ input sections. */

• Specify a file name to include sections from a particular file.
  • For example:

data.o(.data)

• Using a file name without a list of sections, then all sections in the input file will be included in the output section.

#top #sections

• In an input section description, either the file name or the section name or both may be wildcard patterns.
• The wildcard patterns are like those used by the Unix shell.

‘*’	matches any number of characters
‘?’	matches any single character
‘[chars]’	matches a single instance of any of the chars; the ‘-’ character may be used to specify a range of characters, as in ‘[a-z]’ to match any lower case letter
‘\’	quotes the following character

• When a file name is matched with a wildcard, the wildcard characters will not match a ‘/’character.
  • A pattern consisting of a single ‘*’character is an exception; it will always match any file name, whether it contains a ‘/’ or not.
• In a section name, the wildcard characters will match a ‘/’ character.
• File name wildcard patterns only match files which are explicitly specified on the command line or in an INPUT command.
  • The linker does not search directories to expand wildcards.
• If a file name matches more than one wildcard pattern, or if a file name appears explicitly and is also matched by a wildcard pattern, the linker will use the first match in the linker script.
• Using the SORT keyword, which appears before a wildcard pattern in parentheses (e.g., SORT(.text*)), the linker will sort the files or sections into ascending order by name before placing them in the output file.
• Example

SECTIONS {
    .text : { *(.text) }      /* place all ‘.text’ sections in ‘.text’ */
    .DATA : { [A-Z]*(.data) } /* ‘.data’ section from all files beginning with an upper case character in ‘.DATA’*/
    .data : { *(.data) }      /* for all other files, the linker will place the ‘.data’ section in ‘.data’. */
    .bss : { *(.bss) }        /* all ‘.bss’ sections in ‘.bss’*/
}

#top #sections

• A special notation is needed for common symbols, because in many object file formats common symbols do not have a particular input section.
• The linker treats common symbols as though they are in an input section named ‘COMMON’.
• You may use file names with the ‘COMMON’ section just as with any other input sections.
• You can use this to place common symbols from a particular input file in one section while common symbols from other input files are placed in another section.
• In most cases, common symbols in input files will be placed in the ‘.bss’ section in the output file.
• For example:

.bss { *(.bss) *(COMMON) }

• Some object file formats have more than one type of common symbol.
  • For example, the MIPS ELF object file format distinguishes standard common symbols and small common symbols.
• In this case, the linker will use a different special section name for other types of common symbols.
  • In the case of MIPS ELF, the linker uses ‘COMMON’ for standard common symbols and ‘.scommon’ for small common symbols.
• This permits you to map the different types of common symbols into memory at different locations.
• You will sometimes see ‘[COMMON]’ in old linker scripts. This notation is now considered obsolete. It is equivalent to ‘*(COMMON)’

#top #sections

• When link-time garbage collection is in use (‘--gc-sections’), it is often useful to mark sections that should not be eliminated.
• This is accomplished by surrounding an input section’s wildcard entry with KEEP(), as in KEEP(*(.init)) or KEEP(SORT(*)(.ctors)).

#top #sections

All of section ‘.input2’ from ‘foo.o’ goes into output section

‘outputb’, followed by section ‘.input1’ from ‘foo1.o’. All of the remaining ‘.input1’ and
‘.input2’ sections from any files are written to output section ‘outputc’.

SECTIONS {
    outputa 0x10000 :    /* ‘outputa’ starts at location ‘0x10000’ */
    {
        all.o            /* All of the sections from file ‘all.o’ and place them at the start of output section ‘outputa’*/
        foo.o (.input1)  /* All of section ‘.input1’ from file ‘foo.o’ follows immediately */
    }
    outputb :
    {
        foo.o (.input2)  /*  All of section ‘.input2’ from ‘foo.o’ goes into output section ‘outputb' */
        foo1.o (.input1) /*  All of section ‘.input1’ from ‘foo1.o’ */
    }
    outputc :
    {
        *(.input1)       /* All of the remaining ‘.input1’ and ‘.input2’ sections from any files are written to output section ‘outputc’ */
        *(.input2)
    }
}

#top #sections

• Include explicit bytes of data in an output section by using BYTE, SHORT, LONG, QUAD, or SQUAD as an output section command.
  • Each keyword is followed by an expression in parentheses providing the value to store.
  • The value of the expression is stored at the current value of the location counter.
  • The BYTE, SHORT, LONG, and QUAD commands store one, two, four, and eight bytes (respectively).
  • After storing the bytes, the location counter is incremented by the number of bytes stored.
  • For example, this will store the byte 1 followed by the four byte value of the symbol ‘addr’

BYTE(1)
LONG(addr)

• When using a 64 bit host or target, QUAD and SQUAD are the same; they both store an 8 byte, or 64 bit, value.
• When both host and target are 32 bits, an expression is computed as 32 bits. In this case QUAD stores a 32 bit value zero extended to 64 bits, and SQUAD stores

a 32 bit value sign extended to 64 bits.

• If the object file format of the output file has an explicit endianness, which is the normal case, the value will be stored in that endianness.
• When the object file format does not have an explicit endianness, as is true of, for example, S-records, the value will be stored in the endianness of the first input object file.
• Note―these commands only work inside a section description and not between them.

/* SECTIONS { .text : { *(.text) } LONG(1) .data : { *(.data) } } ... will produce an error from the linker: */
SECTIONS { .text : { *(.text) ; LONG(1) } .data : { *(.data) } }   /* OK */

• You may use the FILL command to set the fill pattern for the current section. It is followed by an expression in parentheses.
• Any otherwise unspecified regions of memory within the section (for example, gaps left due to the required alignment of input sections) are filled

with the value of the expression, repeated as necessary.

• A FILL statement covers memory locations after the point at which it occurs in the section definition; by including more than one FILL statement, you can have different fill patterns in different parts of an output section.
• This example shows how to fill unspecified regions of memory with the value ‘0x90’:

FILL(0x90909090)

• The FILL command is similar to the ‘=fillexp’ output section attribute, but it only affects the part of the section following the FILL command, rather than the entire section.
• If both are used, the FILL command takes precedence.

#top #sections

• The command tells the linker to create a symbol for each input file.
• The name of each symbol will be the name of the corresponding input file.
• The section of each symbol will be the output section in which the CREATE_OBJECT_SYMBOLS command appears.
• This is conventional for the a.out object file format. It is not normally used for any other object file format.

• When linking using the a.out object file format, the linker uses an unusual set construct to support C++ global constructors and destructors.
• When linking object file formats which do not support arbitrary sections, such as ECOFF and XCOFF, the linker will automatically recognize C++ global constructors

and destructors by name.

• For these object file formats, the CONSTRUCTORS command tells the linker to place constructor information in the output section where the CONSTRUCTORS command appears.
• The CONSTRUCTORS command is ignored for other object file formats.
• The symbol __CTOR_LIST _{marks the start of the global constructors, and the symbol} DTOR_LIST marks the end.
• The first word in the list is the number of entries, followed by the address of each constructor or destructor, followed by a zero word.
• The compiler must arrange to actually run the code.
• For these object file formats gnu C++ normally calls constructors from a subroutine _{main; a call to} main is automatically inserted into the startup code for main.
• gnu C++ normally runs destructors either by using atexit, or directly from the function exit.
• For object file formats such as COFF or ELF which support arbitrary section names, gnu C++ will normally arrange to put the addresses of global constructors

and destructors into the .ctors and .dtors sections.

• Placing the following sequence into your linker script will build the sort of table which the gnu C++ runtime code expects to see.

__CTOR_LIST__ = .;
LONG((__CTOR_END__ - __CTOR_LIST__) / 4 - 2)
*(.ctors)
LONG(0)
__CTOR_END__ = .;
__DTOR_LIST__ = .;
LONG((__DTOR_END__ - __DTOR_LIST__) / 4 - 2)
*(.dtors)
LONG(0)
__DTOR_END__ = .;

• If you are using the gnu C++ support for initialization priority, which provides some control over the order in which global constructors are run, you must sort

the constructors at link time to ensure that they are executed in the correct order.

• When using the CONSTRUCTORS command, use ‘SORT(CONSTRUCTORS)’instead.
• When using the .ctors and .dtors sections, use ‘*(SORT(.ctors))’and ‘*(SORT(.dtors))’ instead of just ‘*(.ctors)’ and ‘*(.dtors)’.

#top #sections

• The linker will not create output section which do not have any contents.
• This is for convenience when referring to input sections that may or may not be present in any of the input files.
• For example:

.foo { *(.foo) } /* will only create a ‘.foo’ section in the output file if there is a ‘.foo’ section in at least one input file. */

• If you use anything other than an input section description as an output section command, such as a symbol assignment, then the output section will always be created, even if there are no matching input sections.
• The special output section name ‘/DISCARD/’ may be used to discard input sections.
• Any input sections which are assigned to an output section named ‘/DISCARD/’ are not included in the output file.

#top #sections

• Each output section may have a type. The type is a keyword in parentheses. The following types are defined:

NOLOAD	The section should be marked as not loadable, so that it will not be loaded into memory when the program is run.
DSECT COPY INFO OVERLAY	These type names are supported for backward compatibility, and are rarely used. They all have the same effect: the section should be marked as not allocatable, so that no memory is allocated for the section when the program is run.

• The linker normally sets the attributes of an output section based on the input sections which map into it.
• You can override this by using the section type.
  • For example, in the script sample below, the ‘ROM’ section is addressed at memory location ‘0’ and does not need to be loaded when the program is run. The contents of the ‘ROM’ section will appear in the linker output file as usual.

SECTIONS {
    ROM 0 (NOLOAD) : { ... }
    ...
}

#top #sections

• Every section has a virtual address (VMA) and a load address (LMA).
• The address expression which may appear in an output section description sets the VMA.
• The linker will normally set the LMA equal to the VMA.
• You can change that by using the AT keyword.
• The expression lma that follows the AT keyword specifies the load address of the section.
• Alternatively, with ‘AT>lma_region’ expression, you may specify a memory region for the section’s load address.
• This feature is designed to make it easy to build a ROM image.
  • For example, the following linker script creates three output sections: one called ‘.text’, which starts at 0x1000, one called ‘.mdata’, which is loaded at the end of the ‘.text’ section even though its VMA is 0x2000, and one called ‘.bss’ to hold uninitialized data at address 0x3000. The symbol _data is defined with the value 0x2000, which shows that the location counter holds the VMA value, not the LMA value.

SECTIONS
{
    .text 0x1000 : { *(.text) _etext = . ; }
    .mdata 0x2000 :
        AT ( ADDR (.text) + SIZEOF (.text) )
        { _data = . ; *(.data); _edata = . ; }
    .bss 0x3000 :
        { _bstart = . ; *(.bss) *(COMMON) ; _bend = . ;}
}

• The run-time initialization code for use with a program generated with this linker script would include something like the following, to copy the initialized data from the ROM image to its runtime address. Notice how this code takes advantage of the symbols defined by the linker script.

extern char _etext, _data, _edata, _bstart, _bend;
char *src = &_etext;
char *dst = &_data;
/* ROM has data at end of text; copy it. */
while (dst < &_edata) {
    *dst++ = *src++;
}
/* Zero bss */
for (dst = &_bstart; dst< &_bend; dst++)
    *dst = 0;

#top #sections

• You can assign a section to a previously defined region of memory by using ‘>region’
• Here is a simple example:

MEMORY { rom : ORIGIN = 0x1000, LENGTH = 0x1000 }
SECTIONS { ROM : { *(.text) } >rom }

#top #sections

• You can assign a section to a previously defined program segment by using ‘:phdr’.
• If a section is assigned to one or more segments, then all subsequent allocated sections will be assigned to those segments as well, unless they use an explicitly :phdr modifier.
• You can use :NONE to tell the linker to not put the section in any segment at all.
• Here is a simple example:

PHDRS { text PT_LOAD ; }
SECTIONS { .text : { *(.text) } :text }

#top #sections #phdrs

• You can set the fill pattern for an entire section by using ‘=fillexp’.
• fillexp is an expression
• Any otherwise unspecified regions of memory within the output section will be filled with the value, repeated as necessary.
• If the fill expression is a simple hex number, ie. a string of hex digit starting with ‘0x’ and without a trailing ‘k’ or ‘M’, then an arbitrarily long sequence of hex digits can be used to specify the fill pattern;
• Leading zeros become part of the pattern too.
• For all other cases, including extra parentheses or a unary +, the fill pattern is the four least significant bytes of the value of the expression.
• In all cases, the number is big-endian.
• You can also change the fill value with a FILL command in the output section commands.
• Here is a simple example:

SECTIONS { .text : { *(.text) } =0x90909090 }

#top #sections

• An overlay description provides an easy way to describe sections which are to be loaded as part of a single memory image but are to be run at the same memory address.
• At run time, some sort of overlay manager will copy the overlaid sections in and out of the runtime memory address as required, perhaps by simply manipulating addressing bits.
• This approach can be useful, for example, when a certain region of memory is faster than another.
• Overlays are described using the OVERLAY command. The OVERLAY command is used within a SECTIONS command, like an output section description. The full syntax of the OVERLAY command is as follows:

OVERLAY [start] : [NOCROSSREFS] [AT ( ldaddr )]
    {
    secname1
        {
            output-section-command
            output-section-command
            ...
        } [:phdr...] [=fill]
    secname2
        {
            output-section-command
            output-section-command
            ...
        } [:phdr...] [=fill]
        ...
    } [>region] [:phdr...] [=fill]

• Everything is optional except OVERLAY (a keyword), and each section must have a name (secname1 and secname2 above).
• The section definitions within the OVERLAY construct are identical to those within the general SECTIONS contruct,except that no addresses and no memory regions may be defined for sections within an OVERLAY.
• The sections are all defined with the same starting address.
• The load addresses of the sections are arranged such that they are consecutive in memory starting at the load address used for the OVERLAY as a whole (as with normal section definitions, the load address is optional, and defaults to the start address; the start address is also optional, and defaults to the current value of the location counter).
• If the NOCROSSREFS keyword is used, and there any references among the sections, the linker will report an error.
  • Since the sections all run at the same address, it normally does not make sense for one section to refer directly to another.
• For each section within the OVERLAY, the linker automatically defines two symbols.
  • The symbol __load_start_secname is defined as the starting load address of the section.
  • The symbol __load_stop_secname is defined as the final load address of the section. Any characters within secname which are not legal within C identifiers are removed. C (or assembler) code may use these symbols to move the overlaid sections around as necessary.
• At the end of the overlay, the value of the location counter is set to the start address of the overlay plus the size of the largest section.
• Here is an example. Remember that this would appear inside a SECTIONS construct.

OVERLAY 0x1000 : AT (0x4000)
{
    .text0 { o1/*.o(.text) }
    .text1 { o2/*.o(.text) }
}

• This will define both ‘.text0’ and ‘.text1’ to start at address 0x1000. ‘.text0’ will be loaded at address 0x4000, and ‘.text1’ will be loaded immediately after ‘.text0’.
• The following symbols will be defined: __load_start_text0, __load_stop_text0, __load_start_text1, __load_stop_text1.
• C code to copy overlay .text1 into the overlay area might look like the following.

extern char __load_start_text1, __load_stop_text1;
memcpy ((char *) 0x1000, &__load_start_text1,
&__load_stop_text1 - &__load_start_text1);

• Note that the OVERLAY command is just syntactic sugar, since everything it does can be done using the more basic commands.
• The above example could have been written identically as follows.

.text0 0x1000 : AT (0x4000) { o1/*.o(.text) }
__load_start_text0 = LOADADDR (.text0);
__load_stop_text0 = LOADADDR (.text0) + SIZEOF (.text0);
.text1 0x1000 : AT (0x4000 + SIZEOF (.text0)) { o2/*.o(.text) }
__load_start_text1 = LOADADDR (.text1);
__load_stop_text1 = LOADADDR (.text1) + SIZEOF (.text1);
. = 0x1000 + MAX (SIZEOF (.text0), SIZEOF (.text1));

#top #sections

• The linker’s default configuration permits allocation of all available memory.
• You can override this by using the MEMORY command.
• The MEMORY command describes the location and size of blocks of memory in the target.
• You can use it to describe which memory regions may be used by the linker, and which regions it must avoid.
• You can then assign sections to particular memory regions.
• The linker will set section addresses based on the memory regions and will warn about regions that become too full.
• The linker will not shuffle sections around to fit into the available regions.
• A linker script may contain at most one use of the MEMORY command.
• However, you can define as many blocks of memory within it as you wish.
• The syntax is:

MEMORY
{
    name [(attr)] : ORIGIN = origin, LENGTH = len
    ...
}

• The name is a name used in the linker script to refer to the region.
• The region name has no meaning outside of the linker script.
• Region names are stored in a separate name space, and will not conflict with symbol names, file names, or section names.
• Each memory region must have a distinct name.
• The attr string is an optional list of attributes that specify whether to use a particular memory region for an input section which is not explicitly mapped in the linker script.
• If you do not specify an output section for some input section, the linker will create an output section with the same name as the input section.
• If you define region attributes, the linker will use them to select the memory region for the output section that it creates.
• The attr string must consist only of the following characters:

‘R’	Read-only section
‘W’	Read/write section
‘X’	Executable section
‘A’	Allocatable section
‘I’	Initialized section
‘L’	Same as ‘I’
‘!’	Invert the sense of any of the preceding attributes

• If a unmapped section matches any of the listed attributes other than ‘!’, it will be placed in the memory region.
• The ‘!’ attribute reverses this test, so that an unmapped section will be placed in the memory region only if it does not match any of the listed attributes.
• The origin is an expression for the start address of the memory region.
• The expression must evaluate to a constant before memory allocation is performed, which means that you may not use any section relative symbols.
• The keyword ORIGIN may be abbreviated to org or o (but not, for example, ORG).
• The len is an expression for the size in bytes of the memory region.
• As with the origin expression, the expression must evaluate to a constant before memory allocation is performed.
• The keyword LENGTH may be abbreviated to len or l.
• In the following example, we specify that there are two memory regions available for allocation:
  • one starting at ‘0’ for 256 kilobytes, and the other starting at ‘0x40000000’ for four megabytes.
  • The linker will place into the ‘rom’ memory region every section which is not explicitly mapped into a memory region, and is either read-only or executable.
  • The linker will place other sections which are not explicitly mapped into a memory region into the ‘ram’ memory region.

MEMORY
{
    rom (rx) : ORIGIN = 0, LENGTH = 256K
    ram (!rx) : org = 0x40000000, l = 4M
}

• Once you define a memory region, you can direct the linker to place specific output sections into that memory region by using the ‘>region’ output section attribute.
• For example, if you have a memory region named ‘mem’, you would use ‘>mem’ in the output section definition.
• If no address was specified for the output section, the linker will set the address to the next available address within the memory region.
• If the combined output sections directed to a memory region are too large for the region, the linker will issue an error message

#top #sections

• The ELF object file format uses program headers, also knows as segments.
• The program headers describe how the program should be loaded into memory.
• You can print them out by using the objdump program with the ‘-p’ option.
• When you run an ELF program on a native ELF system, the system loader reads the program headers in order to figure out how to load the program.
• This will only work if the program headers are set correctly.
• This manual does not describe the details of how the system loader interprets program headers; for more information, see the ELF ABI.
• The linker will create reasonable program headers by default.
• However, in some cases, you may need to specify the program headers more precisely.
• You may use the PHDRS command for this purpose.
• When the linker sees the PHDRS command in the linker script, it will not create any program headers other than the ones specified.
• The linker only pays attention to the PHDRS command when generating an ELF output file.
• In other cases, the linker will simply ignore PHDRS.
• This is the syntax of the PHDRS command. The words PHDRS, FILEHDR, AT, and FLAGS are keywords.

PHDRS
{
    name type [ FILEHDR ] [ PHDRS ] [ AT ( address ) ]
        [ FLAGS ( flags ) ] ;
}

• The name is used only for reference in the SECTIONS command of the linker script.
• It is not put into the output file.
• Program header names are stored in a separate name space, and will not conflict with symbol names, file names, or section names.
• Each program header must have a distinct name.
• Certain program header types describe segments of memory which the system loader will load from the file.
• In the linker script, you specify the contents of these segments by placing allocatable output sections in the segments.
• You use the ‘:phdr’ output section attribute to place a section in a particular segment.
• It is normal to put certain sections in more than one segment.
• This merely implies that one segment of memory contains another.
• You may repeat ‘:phdr’, using it once for each segment which should contain the section.
• If you place a section in one or more segments using ‘:phdr’, then the linker will place all subsequent allocatable sections which do not specify ‘:phdr’ in the same segments.
• This is for convenience, since generally a whole set of contiguous sections will be placed in a single segment.
• You can use :NONE to override the default segment and tell the linker to not put the section in any segment at all.
• You may use the FILEHDR and PHDRS keywords appear after the program header type to further describe the contents of the segment.
• The FILEHDR keyword means that the segment should include the ELF file header.
• The PHDRS keyword means that the segment should include the ELF program headers themselves.
• The type may be one of the following. The numbers indicate the value of the keyword.

PT_NULL (0)	Indicates an unused program header.
PT_LOAD (1)	Indicates that this program header describes a segment to be loaded from the file.
PT_DYNAMIC (2)	Indicates a segment where dynamic linking information can be found.
PT_INTERP (3)	Indicates a segment where the name of the program interpreter may be found.
PT_NOTE (4)	Indicates a segment holding note information.
PT_SHLIB (5)	A reserved program header type, defined but not specified by the ELF ABI.
PT_PHDR (6)	Indicates a segment where the program headers may be found.
expression	An expression giving the numeric type of the program header. This may be used for types not defined above.

• You can specify that a segment should be loaded at a particular address in memory by using an AT expression.
• This is identical to the AT command used as an output section attribute .
• The AT command for a program header overrides the output section attribute.
• The linker will normally set the segment flags based on the sections which comprise the segment.
• You may use the FLAGS keyword to explicitly specify the segment flags.
• The value of flags must be an integer.
• It is used to set the p_flags field of the program header.
• Here is an example of PHDRS. This shows a typical set of program headers used on a native ELF system.

PHDRS
{
    headers PT_PHDR PHDRS ;
    interp PT_INTERP ;
    text PT_LOAD FILEHDR PHDRS ;
    data PT_LOAD ;
    dynamic PT_DYNAMIC ;
}
SECTIONS
{
    . = SIZEOF_HEADERS;
    .interp : { *(.interp) } :text :interp
    .text : { *(.text) } :text
    .rodata : { *(.rodata) } /* defaults to :text */
    ...
    . = . + 0x1000; /* move to a new page in memory */
    .data : { *(.data) } :data
    .dynamic : { *(.dynamic) } :data :dynamic
    ...
}

#top #sections

• The linker supports symbol versions when using ELF.
• Symbol versions are only useful when using shared libraries.
• The dynamic linker can use symbol versions to select a specific version of a function when it runs a program that may have been linked against an earlier version of the shared library.

#top #sections

• The syntax for expressions in the linker script language is identical to that of C expressions.
• All expressions are evaluated as integers.
• All expressions are evaluated in the same size, which is 32 bits if both the host and target are 32 bits, and is otherwise 64 bits.
• You can use and set symbol values in expressions.
• The linker defines several special purpose builtin functions for use in expressions.

#top #express

• All constants are integers.
• As in C, the linker considers an integer beginning with ‘0’ to be octal, and an integer beginning with ‘0x’ or ‘0X’ to be hexadecimal.
• The linker considers other integers to be decimal.
• In addition, you can use the suffixes K and M to scale a constant by 1024 or 10242 respectively.
• For example, the following all refer to the same quantity:

_fourk_1 = 4K;
_fourk_2 = 4096;
_fourk_3 = 0x1000;

#top #express

• Unless quoted, symbol names start with a letter, underscore, or period and may include letters, digits, underscores, periods, and hyphens.
• Unquoted symbol names must not conflict with any keywords.
• You can specify a symbol which contains odd characters or has the same name as a keyword by surrounding the symbol name in double quotes:

"SECTION" = 9;
"with a space" = "also with a space" + 10;

• Since symbols can contain many non-alphabetic characters, it is safest to delimit symbols with spaces.
• For example, ‘A-B’ is one symbol, whereas ‘A - B’ is an expression involving subtraction.

#top #express

• The special linker variable dot ‘.’ always contains the current output location counter.
• Since the . always refers to a location in an output section, it may only appear in an expression within a SECTIONS command.
• The . symbol may appear anywhere that an ordinary symbol is allowed in an expression.
• Assigning a value to . will cause the location counter to be moved.
• This may be used to create holes in the output section.
• The location counter may never be moved backwards.

SECTIONS
{
    output :
    {
        file1(.text)
        . = . + 1000;
        file2(.text)
        . += 1000;
        file3(.text)
    } = 0x12345678;
}

• In the previous example, the ‘.text’ section from ‘file1’ is located at the beginning of the output section ‘output’.
• It is followed by a 1000 byte gap.
• Then the ‘.text’ section from ‘file2’ appears, also with a 1000 byte gap following before the ‘.text’ section from ‘file3’.
• The notation ‘= 0x12345678’ specifies what data to write in the gaps
• Note: . actually refers to the byte offset from the start of the current containing object.
• Normally this is the SECTIONS statement, whose start address is 0, hence . can be used as an absolute address.
• If . is used inside a section description however, it refers to the byte offset from the start of that section, not an absolute address.
• Thus in a script like this:

SECTIONS
{
    . = 0x100
    .text: {
        *(.text)
        . = 0x200
    }
    . = 0x500
    .data: {
        *(.data)
        . += 0x600
    }
}

• The ‘.text’ section will be assigned a starting address of 0x100 and a size of exactly 0x200 bytes, even if there is not enough data in the ‘.text’ input sections to fill this area. (If there is too much data, an error will be produced because this would be an attempt to move . backwards).
• The ‘.data’ section will start at 0x500 and it will have an extra 0x600 bytes worth of space after the end of the values from the ‘.data’ input sections and before the end of the ‘.data’ output section itself.

#top #express

• The linker recognizes the standard C set of arithmetic operators, with the standard bindings and precedence levels:

Precedence	Associativity	Operators	ref
highest
1	left	- ~ !	Prefix operators
2	left	* / %
3	left	+ -
4	left	>> <<
5	left	== != > < <= >=
6	left	&
7	left	|
8	left	&&
9	left	||
10	right	? :
11	right	&= += -= *= /=	Assignments
lowest

#top #express

The linker evaluates expressions lazily. It only computes the value of an expression when
absolutely necessary.
The linker needs some information, such as the value of the start address of the first section,
and the origins and lengths of memory regions, in order to do any linking at all. These
values are computed as soon as possible when the linker reads in the linker script.
However, other values (such as symbol values) are not known or needed until after storage
allocation. Such values are evaluated later, when other information (such as the sizes of
output sections) is available for use in the symbol assignment expression.
The sizes of sections cannot be known until after allocation, so assignments dependent upon
these are not performed until after allocation.
Some expressions, such as those depending upon the location counter ‘.’, must be evaluated
during section allocation.
If the result of an expression is required, but the value is not available, then an error results.
For example, a script like the following
SECTIONS
{
.text 9+this_isnt_constant :
{ *(.text) }
}
will cause the error message ‘non constant expression for initial address’.
#top #express

When the linker evaluates an expression, the result is either absolute or relative to some
section. A relative expression is expressed as a fixed offset from the base of a section.
The position of the expression within the linker script determines whether it is absolute or
relative. An expression which appears within an output section definition is relative to the
base of the output section. An expression which appears elsewhere will be absolute.
A symbol set to a relative expression will be relocatable if you request relocatable output
using the ‘-r’ option. That means that a further link operation may change the value of
the symbol. The symbol’s section will be the section of the relative expression.
A symbol set to an absolute expression will retain the same value through any further link
operation. The symbol will be absolute, and will not have any particular associated section.
You can use the builtin function ABSOLUTE to force an expression to be absolute when it
would otherwise be relative. For example, to create an absolute symbol set to the address
of the end of the output section ‘.data’:
SECTIONS
{
.data : { *(.data) _edata = ABSOLUTE(.); }
}
If ‘ABSOLUTE’ were not used, ‘_edata’ would be relative to the ‘.data’ section.
#top #express

The linker script language includes a number of builtin functions for use in linker script
expressions.
ABSOLUTE(exp)
Return the absolute (non-relocatable, as opposed to non-negative) value of the
expression exp. Primarily useful to assign an absolute value to a symbol within
a section definition, where symbol values are normally section relative. See
Section 3.10.6 [Expression Section], page 55.
ADDR(section)
Return the absolute address (the VMA) of the named section. Your script must
previously have defined the location of that section. In the following example,
symbol_1 and symbol_2 are assigned identical values:
SECTIONS { ...
.output1 :
{
start_of_output_1 = ABSOLUTE(.);
...
}
.output :
{
symbol_1 = ADDR(.output1);
symbol_2 = start_of_output_1;
}
... }
ALIGN(exp)
Return the location counter (.) aligned to the next exp boundary. ALIGN
doesn’t change the value of the location counter―it just does arithmetic on it.
Here is an example which aligns the output .data section to the next 0x2000
byte boundary after the preceding section and sets a variable within the section
to the next 0x8000 boundary after the input sections:
SECTIONS { ...
.data ALIGN(0x2000): {

variable = ALIGN(0x8000);
}
... }
The first use of ALIGN in this example specifies the location of a section because
it is used as the optional address attribute of a section definition (see
Section 3.6.3 [Output Section Address], page 37). The second use of ALIGN is
used to defines the value of a symbol.
The builtin function NEXT is closely related to ALIGN.
BLOCK(exp)
This is a synonym for ALIGN, for compatibility with older linker scripts. It is
most often seen when setting the address of an output section.
DATA_SEGMENT_ALIGN(maxpagesize, commonpagesize)
This is equivalent to either
(ALIGN(maxpagesize) + (. & (maxpagesize - 1)))
or
(ALIGN(maxpagesize) + (. & (maxpagesize - commonpagesize)))
depending on whether the latter uses fewer commonpagesize sized pages for the
data segment (area between the result of this expression and DATA_SEGMENT_
END) than the former or not. If the latter form is used, it means commonpagesize
bytes of runtime memory will be saved at the expense of up to commonpagesize
wasted bytes in the on-disk file.
This expression can only be used directly in SECTIONS commands, not in any
output section descriptions and only once in the linker script. commonpagesize
should be less or equal to maxpagesize and should be the system page size the
object wants to be optimized for (while still working on system page sizes up
to maxpagesize).
Example:
. = DATA_SEGMENT_ALIGN(0x10000, 0x2000);
DATA_SEGMENT_END(exp)
This defines the end of data segment for DATA_SEGMENT_ALIGN evaluation purposes.
. = DATA_SEGMENT_END(.);
DEFINED(symbol)
Return 1 if symbol is in the linker global symbol table and is defined, otherwise
return 0. You can use this function to provide default values for symbols.
For example, the following script fragment shows how to set a global symbol
‘begin’ to the first location in the ‘.text’ section―but if a symbol called ‘begin’
already existed, its value is preserved:
SECTIONS { ...
.text : {
begin = DEFINED(begin) ? begin : . ;
...
}
...
}
LOADADDR(section)
Return the absolute LMA of the named section. This is normally the same as
ADDR, but it may be different if the AT attribute is used in the output section
definition (see Section 3.6.8.2 [Output Section LMA], page 43).
MAX(exp1, exp2)
Returns the maximum of exp1 and exp2.
MIN(exp1, exp2)
Returns the minimum of exp1 and exp2.
NEXT(exp)
Return the next unallocated address that is a multiple of exp. This function is
closely related to ALIGN(exp); unless you use the MEMORY command to define
discontinuous memory for the output file, the two functions are equivalent.
SIZEOF(section)
Return the size in bytes of the named section, if that section has been allocated.
If the section has not been allocated when this is evaluated, the linker will
report an error. In the following example, symbol_1 and symbol_2 are assigned
identical values:
SECTIONS{ ...
.output {
.start = . ;
...
.end = . ;
}
symbol_1 = .end - .start ;
symbol_2 = SIZEOF(.output);
... }
SIZEOF_HEADERS
sizeof_headers
Return the size in bytes of the output file’s headers. This is information which
appears at the start of the output file. You can use this number when setting
the start address of the first section, if you choose, to facilitate paging.
When producing an ELF output file, if the linker script uses the SIZEOF_
HEADERS builtin function, the linker must compute the number of program
headers before it has determined all the section addresses and sizes. If the
linker later discovers that it needs additional program headers, it will report an
error ‘not enough room for program headers’. To avoid this error, you must
avoid using the SIZEOF_HEADERS function, or you must rework your linker script
to avoid forcing the linker to use additional program headers, or you must define
the program headers yourself using the PHDRS command (see Section 3.8
[PHDRS], page 48).
#top #express

If you specify a linker input file which the linker can not recognize as an object file or an
archive file, it will try to read the file as a linker script. If the file can not be parsed as a
linker script, the linker will report an error.
An implicit linker script will not replace the default linker script.
Typically an implicit linker script would contain only symbol assignments, or the INPUT,
GROUP, or VERSION commands.
Any input files read because of an implicit linker script will be read at the position in the
command line where the implicit linker script was read. This can affect archive searching.
#top #express

• Assigning a value to a symbol in a linker script will define the symbol as a global symbol.

symbol = expression ;
symbol += expression ;
symbol -= expression ;
symbol *= expression ;
symbol /= expression ;
symbol <<= expression ;
symbol >>= expression ;
symbol &= expression ;
symbol |= expression ;

The semicolon after expression is required.
#top

The special symbol name ‘.’ indicates the location counter. You may only use this within a SECTIONS command.

floating_point = 0;
SECTIONS
{
	.text :
	{
		*(.text)
		_etext = .;
	}
	_bdata = (. + 3) & ~ 3;
	.data : { *(.data) }
}

#top

A linker script can define a symbol only if it is referenced and is not defined by any object included in the link.

• Each object file has a list of sections.
• Each section has a name and a size.
• Most sections also have an associated block of data (the section contents).
  • A section may be marked as loadable, which mean that the contents should be loaded into memory when the output file is run.
  • A section with no contents may be allocatable, which means that an area in memory should be set aside, but nothing in particular should be loaded there (in some cases this memory must be zeroed out).
  • A section which is neither loadable nor allocatable typically contains some sort of debugging information.

• Every loadable or allocatable output section has two addresses. VMA and LMA.
  • VMA(virtual memory address) is the address the section will have when the output file is run.
  • LMA(load memory address) is the address at which the section will be loaded.
  • In most cases the two addresses will be the same.
  • When copying ROM to RAM, the ROM address would be the LMA, and the RAM address would be the VMA.
• To see the sections in an object file, use the objdump program with the ‘-h’ option.
• Every object file also has a list of symbols (the symbol table).
  • A symbol may be defined or undefined. Each symbol has a name, and each defined symbol has an address, among other information.
  • In case compiling a C or C++ program into an object file,
    • Every defined function and global or static variable will be a defined symbol.
    • Every undefined function or global variable which is referenced in the input file will become an undefined symbol.
  • To see the symbols in an object file,use the nm program, or use the objdump program with the ‘-t’ option.

#top

• Linker scripts are text files.
• Write a linker script as a series of commands.
• Each command is either a keyword, possibly followed by arguments, or an assignment to a symbol.
• To separate commands, use semicolons.
• Whitespace is generally ignored.
• Strings such as file or format names can normally be entered directly.
  • If the file name contains a character such as a comma which would otherwise serve to separate file names, you may put the file name in double quotes.
  • There is no way to use a double quote character in a file name.
• Comments in linker scripts are delimited by ‘/*’ and ‘*/’.
  • As in C, comments are syntactically equivalent to whitespace.

#top

Overlays
NOCROSSREFS
#top

If you ever get confused about where input sections are going, use the ‘-M’ linker option to generate a map file. The map file shows precisely how input sections are mapped to output sections.

• The program headers describe how the program should be loaded into memory.
• You can print them out by using the objdump program with the ‘-p’ option.

SECTIONS
{
. = 0x10000;          /* load address */ /* the special symbol ‘.’(the location counter) is set. */
.text : { *(.text) }  /* code */
. = 0x8000000;        /* data start address */
.data : { *(.data) }  /* initialized data */
.bss : { *(.bss) }   /* uninitialized data */
}

• At the start of the ‘SECTIONS’ command, the location counter has the value ‘0’.
• Within the curly braces after the output section name(.text :), list the names of the input sections which should be placed into this output section.
• The expression ‘*(.text)’ means all ‘.text’ input sections in all input files.

#top

/* linkerscript.ls */
OUTPUT_ARCH(i386);
SECTIONS {
	. = 0x1000;
	.ipl 0x1000 : AT(0x7C00){
		ipl.o;		/* this has to be here */
		_setup_load_point = .;
		vbe.o;
		setup.o;    /* this has to follow it */
		*(EXCLUDE_FILE(ipl.o setup.o)*); /* any order */
		. = ALIGN(32); /* fill with 0 */
	}
	_initial_stack_pointer = ADDR(.ipl);
	_loaded_address = LOADADDR(.ipl);
	_fdimage_end_sector = (SIZEOF(.ipl) / 512) + 1; 
	_free_area = . ; /*  */
	_idt0 = (0xA0000 - 8192*8 - 256* 8 ); /* = 0xA0000-0x10800 = 0x8F800 */
	_gdt0 = (0xA0000 - 8192*8) ; /* = 0xA0000-0x10000 = 0x90000 */
	_bios_info = _idt0; /* transfer BIOS config info to env.c */
}
ASSERT( (_initial_stack_pointer == 0x1000), "not 0x1000");
ASSERT( (SIZEOF(.ipl) <= 1440K), "image size is bigger than 1440K");
/* ASSERT( (_free_area <= 0xFFFF), "image size is bigger than 0xFFFF"); */
/* ASSERT( (_free_area <= 0x20000), "image size is bigger than 0x20000"); */

#top

$ ld --verbose
GNU ld (GNU Binutils) 2.24.51.20140623
  サポートされているエミュレーション:
   i386pe
内部リンカスクリプトを使用しています:
==================================================
/* Default linker script, for normal executables */
OUTPUT_FORMAT(pei-i386)
SEARCH_DIR("/usr/i686-pc-cygwin/lib"); SEARCH_DIR("/usr/lib"); SEARCH_DIR("/usr/lib/w32api");
SECTIONS
{
  /* Make the virtual address and file offset synced if the alignment is
     lower than the target page size. */
  . = SIZEOF_HEADERS;
  . = ALIGN(__section_alignment__);
  .text  __image_base__ + ( __section_alignment__ < 0x1000 ? . : __section_alignment__ ) :
  {
     *(.init)
    *(.text)
    *(SORT(.text$*))
     *(.text.*)
     *(.gnu.linkonce.t.*)
    *(.glue_7t)
    *(.glue_7)
     ___CTOR_LIST__ = .; __CTOR_LIST__ = . ;
			LONG (-1);*(.ctors); *(.ctor); *(SORT(.ctors.*));  LONG (0);
     ___DTOR_LIST__ = .; __DTOR_LIST__ = . ;
			LONG (-1); *(.dtors); *(.dtor); *(SORT(.dtors.*));  LONG (0);
     *(.fini)
    /* ??? Why is .gcc_exc here?  */
     *(.gcc_exc)
    PROVIDE (etext = .);
    PROVIDE (_etext = .);
     *(.gcc_except_table)
  }
  /* The Cygwin32 library uses a section to avoid copying certain data
     on fork.  This used to be named ".data".  The linker used
     to include this between __data_start__ and __data_end__, but that
     breaks building the cygwin32 dll.  Instead, we name the section
     ".data_cygwin_nocopy" and explicitly include it after __data_end__. */
  .data BLOCK(__section_alignment__) :
  {
    __data_start__ = . ;
    *(.data)
    *(.data2)
    *(SORT(.data$*))
    *(.jcr)
    __data_end__ = . ;
    *(.data_cygwin_nocopy)
  }
  .rdata BLOCK(__section_alignment__) :
  {
    *(.rdata)
             *(SORT(.rdata$*))
    __rt_psrelocs_start = .;
    *(.rdata_runtime_pseudo_reloc)
    __rt_psrelocs_end = .;
  }
  __rt_psrelocs_size = __rt_psrelocs_end - __rt_psrelocs_start;
  ___RUNTIME_PSEUDO_RELOC_LIST_END__ = .;
  __RUNTIME_PSEUDO_RELOC_LIST_END__ = .;
  ___RUNTIME_PSEUDO_RELOC_LIST__ = . - __rt_psrelocs_size;
  __RUNTIME_PSEUDO_RELOC_LIST__ = . - __rt_psrelocs_size;
  .eh_frame BLOCK(__section_alignment__) :
  {
    *(.eh_frame*)
  }
  .pdata BLOCK(__section_alignment__) :
  {
    *(.pdata)
  }
  .bss BLOCK(__section_alignment__) :
  {
    __bss_start__ = . ;
    *(.bss)
    *(COMMON)
    __bss_end__ = . ;
  }
  .edata BLOCK(__section_alignment__) :
  {
    *(.edata)
  }
  /DISCARD/ :
  {
    *(.debug$S)
    *(.debug$T)
    *(.debug$F)
    *(.drectve)
     *(.note.GNU-stack)
     *(.gnu.lto_*)
  }
  .idata BLOCK(__section_alignment__) :
  {
    /* This cannot currently be handled with grouped sections.
	See pe.em:sort_sections.  */
    SORT(*)(.idata$2)
    SORT(*)(.idata$3)
    /* These zeroes mark the end of the import list.  */
    LONG (0); LONG (0); LONG (0); LONG (0); LONG (0);
    SORT(*)(.idata$4)
    __IAT_start__ = .;
    SORT(*)(.idata$5)
    __IAT_end__ = .;
    SORT(*)(.idata$6)
    SORT(*)(.idata$7)
  }
  .CRT BLOCK(__section_alignment__) :
  {
    ___crt_xc_start__ = . ;
    *(SORT(.CRT$XC*))  /* C initialization */
    ___crt_xc_end__ = . ;
    ___crt_xi_start__ = . ;
    *(SORT(.CRT$XI*))  /* C++ initialization */
    ___crt_xi_end__ = . ;
    ___crt_xl_start__ = . ;
    *(SORT(.CRT$XL*))  /* TLS callbacks */
    /* ___crt_xl_end__ is defined in the TLS Directory support code */
    ___crt_xp_start__ = . ;
    *(SORT(.CRT$XP*))  /* Pre-termination */
    ___crt_xp_end__ = . ;
    ___crt_xt_start__ = . ;
    *(SORT(.CRT$XT*))  /* Termination */
    ___crt_xt_end__ = . ;
  }
  /* Windows TLS expects .tls$AAA to be at the start and .tls$ZZZ to be
     at the end of section.  This is important because _tls_start MUST
     be at the beginning of the section to enable SECREL32 relocations with TLS
     data.  */
  .tls BLOCK(__section_alignment__) :
  {
    ___tls_start__ = . ;
    *(.tls$AAA)
    *(.tls)
    *(.tls$)
    *(SORT(.tls$*))
    *(.tls$ZZZ)
    ___tls_end__ = . ;
  }
  .endjunk BLOCK(__section_alignment__) :
  {
    /* end is deprecated, don't use it */
    PROVIDE (end = .);
    PROVIDE ( _end = .);
     __end__ = .;
  }
  .rsrc BLOCK(__section_alignment__) : SUBALIGN(4)
  {
    *(.rsrc)
    *(.rsrc$*)
  }
  .reloc BLOCK(__section_alignment__) :
  {
    *(.reloc)
  }
  .stab BLOCK(__section_alignment__) (NOLOAD) :
  {
    *(.stab)
  }
  .stabstr BLOCK(__section_alignment__) (NOLOAD) :
  {
    *(.stabstr)
  }
  /* DWARF debug sections.
     Symbols in the DWARF debugging sections are relative to the beginning
     of the section.  Unlike other targets that fake this by putting the
     section VMA at 0, the PE format will not allow it.  */
  /* DWARF 1.1 and DWARF 2.  */
  .debug_aranges BLOCK(__section_alignment__) (NOLOAD) :
  {
    *(.debug_aranges)
  }
  .zdebug_aranges BLOCK(__section_alignment__) (NOLOAD) :
  {
    *(.zdebug_aranges)
  }
  .debug_pubnames BLOCK(__section_alignment__) (NOLOAD) :
  {
    *(.debug_pubnames)
  }
  .zdebug_pubnames BLOCK(__section_alignment__) (NOLOAD) :
  {
    *(.zdebug_pubnames)
  }
  .debug_pubtypes BLOCK(__section_alignment__) (NOLOAD) :
  {
    *(.debug_pubtypes)
  }
  .zdebug_pubtypes BLOCK(__section_alignment__) (NOLOAD) :
  {
    *(.zdebug_pubtypes)
  }
  /* DWARF 2.  */
  .debug_info BLOCK(__section_alignment__) (NOLOAD) :
  {
    *(.debug_info .gnu.linkonce.wi.*)
  }
  .zdebug_info BLOCK(__section_alignment__) (NOLOAD) :
  {
    *(.zdebug_info .zdebug.gnu.linkonce.wi.*)
  }
  .debug_abbrev BLOCK(__section_alignment__) (NOLOAD) :
  {
    *(.debug_abbrev)
  }
  .zdebug_abbrev BLOCK(__section_alignment__) (NOLOAD) :
  {
    *(.zdebug_abbrev)
  }
  .debug_line BLOCK(__section_alignment__) (NOLOAD) :
  {
    *(.debug_line)
  }
  .zdebug_line BLOCK(__section_alignment__) (NOLOAD) :
  {
    *(.zdebug_line)
  }
  .debug_frame BLOCK(__section_alignment__) (NOLOAD) :
  {
    *(.debug_frame*)
  }
  .zdebug_frame BLOCK(__section_alignment__) (NOLOAD) :
  {
    *(.zdebug_frame*)
  }
  .debug_str BLOCK(__section_alignment__) (NOLOAD) :
  {
    *(.debug_str)
  }
  .zdebug_str BLOCK(__section_alignment__) (NOLOAD) :
  {
    *(.zdebug_str)
  }
  .debug_loc BLOCK(__section_alignment__) (NOLOAD) :
  {
    *(.debug_loc)
  }
  .zdebug_loc BLOCK(__section_alignment__) (NOLOAD) :
  {
    *(.zdebug_loc)
  }
  .debug_macinfo BLOCK(__section_alignment__) (NOLOAD) :
  {
    *(.debug_macinfo)
  }
  .zdebug_macinfo BLOCK(__section_alignment__) (NOLOAD) :
  {
    *(.zdebug_macinfo)
  }
  /* SGI/MIPS DWARF 2 extensions.  */
  .debug_weaknames BLOCK(__section_alignment__) (NOLOAD) :
  {
    *(.debug_weaknames)
  }
  .zdebug_weaknames BLOCK(__section_alignment__) (NOLOAD) :
  {
    *(.zdebug_weaknames)
  }
  .debug_funcnames BLOCK(__section_alignment__) (NOLOAD) :
  {
    *(.debug_funcnames)
  }
  .zdebug_funcnames BLOCK(__section_alignment__) (NOLOAD) :
  {
    *(.zdebug_funcnames)
  }
  .debug_typenames BLOCK(__section_alignment__) (NOLOAD) :
  {
    *(.debug_typenames)
  }
  .zdebug_typenames BLOCK(__section_alignment__) (NOLOAD) :
  {
    *(.zdebug_typenames)
  }
  .debug_varnames BLOCK(__section_alignment__) (NOLOAD) :
  {
    *(.debug_varnames)
  }
  .zdebug_varnames BLOCK(__section_alignment__) (NOLOAD) :
  {
    *(.zdebug_varnames)
  }
  .debug_macro BLOCK(__section_alignment__) (NOLOAD) :
  {
    *(.debug_macro)
  }
  .zdebug_macro BLOCK(__section_alignment__) (NOLOAD) :
  {
    *(.zdebug_macro)
  }
  /* DWARF 3.  */
  .debug_ranges BLOCK(__section_alignment__) (NOLOAD) :
  {
    *(.debug_ranges)
  }
  .zdebug_ranges BLOCK(__section_alignment__) (NOLOAD) :
  {
    *(.zdebug_ranges)
  }
  /* DWARF 4.  */
  .debug_types BLOCK(__section_alignment__) (NOLOAD) :
  {
    *(.debug_types .gnu.linkonce.wt.*)
  }
  .zdebug_types BLOCK(__section_alignment__) (NOLOAD) :
  {
    *(.zdebug_types .gnu.linkonce.wt.*)
  }
}


==================================================

#top

Memory Sections
Designing Linker Scripts with GNU Linker
10. C Startup
lma != vma
STM32用リンカスクリプトを書く
AKI-SH2/7045プログラム実行コードと変数のメモリへの割付について
Command Language
Re: linker script symbols to c source variables
A Sample Linker Script