eraシリーズを語るスレ　まとめWiki　V3

str型(string型、文字列型) 変数の中身が文字の変数 数字を含めあらゆるデータを格納できる
int型(数値型) 変数の中身が数字の変数 数字しか入れられないが、計算に強い

@XXXX;口上用の関数
#DIM DYNAMIC CHRISTMAS

#DIM SAVEDATA KOJOFLAG3, 10

#DIM SAVEDATA CHARADATA KOJOFLAG, 100

IF FLAG:0 == 0
    PRINTW FLAG:0の中身は0です
ELSEIF FLAG:0 == 1
    PRINTW FLAG:0の中身は1です
ELSE
    PRINTW FLAG:0の中身は0でも1でもありません
ENDIF

SELECTCASE FLAG:0
    CASE 0
        PRINTW FLAG:0の中身は0です
    CASE 1
        PRINTW FLAG:0の中身は1です
    CASEELSE
        PRINTW FLAG:0の中身は0でも1でもありません
ENDSELECT

プログラムを最初から最後まで続けて書くとわかりづらいものです。
部分部分に切り分けてわかりやすくするためには、「関数」を使います。

PRINTFORMW これは口上です

CALL KANSUU

@KANSUU
PRINTFORMW 関数が呼ばれました

@KANSUU

PRINTFORMW 家を出て羽田空港につきました
CALL USA
PRINTFORMW 羽田空港から家に戻りました

@USA
PRINTFORMW 国際便でアメリカ旅行して戻ってきました

CALL 関数

@関数
PRINTFORMW 関数が呼ばれました

@TEST
#DIM INT

INT = 123
STR = ABC

PRINTFORMW {INT} %STR%

PRINTFORML 主人:%CALLNAME:MASTER% {DAY}日目 所持金:{MONEY}円

@TEST
#DIM INT
#DIM PLUS

PLUS = 45
INT = 123+PLUS

PRINTFORMW {INT}

@TEST
#DIM INT
#DIM PLUS

PLUS = 45
INT = 123

PRINTFORMW {INT+PLUS}

IF CFLAG:0 >= 1
  PRINTFORMW CFLAG:TARGET:0は1以上です
ELSE
  PRINTFORMW CFLAG:TARGET:0は0以下です
ENDIF

X < Y , XがY未満の場合
X > Y , YがX未満の場合
X >= Y , XがY以上の場合
X <= Y , YがX以上の場合
X == Y , XとYが等しい場合
X != Y , XとYが等しくない場合

IF X+Y >= 10
  PRINTFORMW {X}+{Y}は10以上です
ELSE
  PRINTFORMW {X}+{Y}は10未満です
ENDIF

IF 1
  PRINTFORMW trueです
ELSE
  PRINTFORMW falseです
ENDIF

IF 0
  PRINTFORMW falseです
ELSE
  PRINTFORMW trueです
ENDIF

IF MONEY
  PRINTFORMW お金を持っています 所持金は{MONEY}円です
ELSE
  PRINTFORMW 所持金は0円です
ENDIF

条件式1 && 条件式2 , 条件式1と2を両方満たす場合に分岐を実行(true)
条件式1 || 条件式2 , 条件式1か2、どちらかを満たす場合に分岐を実行
!条件式 , 条件式が満たされていた場合にfalseを、満たしてないとtrueになる

IF CFLAG:0 == 0 && FLAG:0 == 0 && STR:0 == ""
  PRINTFORMW CFLAG:0とFLAG:0とSTR:0には何も代入されていません
ENDIF

IF CFLAG:0 != 0 || FLAG:0 != 0 || STR:0 != ""
  PRINTFORMW CFLAG:0とFLAG:0とSTR:0のどれかに値が代入されています
ENDIF

IF (CFLAG:0 == 0 || (FLAG:0 == 0 && STR:0 == "") || TEQUIP:0 == 0) && (CSTR:0 == "" || TFLAG:0 == 0)
  PRINTFORMW ???
ENDIF

IF (CFLAG:0 == 0 || FLAG:0 == 0) && STR:0 == ""
  PRINTFORMW CFLAG:0とFLAG:0のどちらかは0で、かつSTR:0は空文字列です
ENDIF

@TEST
#DIM DYNAMIC INT

INT = 1
STR = AAA
PRINTFORMW INTは{INT}です STRは%STR%です

@TEST
#DIM DYNAMIC INT, 2

INT:0 = 1
INT:1 = INT:0

STR:0 = AAA
STR:1 = STR:0

PRINTFORMW INT:1は{INT:1}です STR:1は%STR:1%です

STR:1 = STR:0
↓
STR:1 = %STR:0%

@TEST
#DIM DYNAMIC INT, 2

INT:0 = 1
INT:1 = INT:0+3

STR:0 = AAA
STR:1 = BBB%STR:0%CCC

PRINTFORMW INT:1は{INT:1}です STR:1は%STR:1%です

STR:0 = AAA
STR:1 '= STR:0

PRINTFORMW STR:1は%STR:1%です

STR:0 = AAA
STR:1 '= @"BBB%STR:0%CCC"

PRINTFORMW STR:1は%STR:1%です

STR:0 = AAA
STR:1 '= "BBB%STR:0%CCC"

PRINTFORMW STR:1は%STR:1%です

@TEST
STR = AAA

IF STR == "AAA"
  PRINTFORMW STRはAAAです
ELSEIF STR != "AAA"
  PRINTFORMW STRはAAAではありません
ENDIF

@TEST
STR:0 = AAA
STR:1 = AAA

IF STR:0 == STR:1
  PRINTFORMW STR:0は%STR:1%です
ELSEIF STR:0 != STR:1
  PRINTFORMW STR:0は%STR:1%ではありません
ENDIF

    STR:0 = % "あ" * 10 %
    PRINTFORML STR:0 = "%STR:0%"
    WAIT
　;結果
　STR:0 = "ああああああああああ"

STR:0 = AAA
STR:1 = BBB
STR:2 = %STR:0+STR:1%

PRINTFORMW STR:2は%STR:2%です

STR:2 = %STR:0%%STR:1%

STR = AAA
STR += "BBB"
STR += "CCC"

PRINTFORMW STRは%STR%です

STR = 今日は

IF RAND:2
  STR += "カレー"
ELSE
  STR += "オムライス"
ENDIF

STR += "が食べたい"

PRINTFORMW %STR%

PRINTL 改行して表示します
PRINTW 改行してウェイトします

PRINT 改行しません
PRINTL が上の行から続けて表示、改行します

STR = AAA

PRINTW STRの中身は%STR%です
PRINTFORMW STRの中身は%STR%です

STRの中身は%STR%です
STRの中身はAAAです

PRINTFORMW パーセントを表示します \%
PRINTFORMW 中括弧を表示します \{

• PRINTSINGLE系
  • 画面端で折り返さないPRINT 万が一の文字列超過で表示を崩さないために使うけど、画面端に飛び出てる時点で表示が崩れてるので画面サイズを見直したほうが良いと思われる

• PRINTC系
  • コマンドや選択肢を一定間隔で揃えたい几帳面な製作者には重要
  • コンフィグで指定した数だけ表示したら自動で改行してくれる ただしボタンじゃない文章は自動改行しない

• PRINTDATA系
  • 複数の文章からどれか1行をランダムで表示する
  • RAND:XXを使う乱数分岐を幾分スマートにできるものの、変数の代入や計算、他の命令を割り込ませることはできないので、本当に一言表示するだけの場面で使う（口上など）

• PRINTBUTTON系
  • eraでは[]で括った数字が自動でマウスクリックに対応したボタンになる
  • [1]だったら1のボタンといったように、本来では数字しか指定できないボタンを、文字列型を返すようにしたりできる

• PRINTPLAIN系
  • 上記のボタン化の仕様は一行全てに適用される。そのためPRINT(LでもWでもない)で複数の文を一行で表示すると、勝手にボタンとしてまとめられる
  • このボタン化を防ぐためにはPRINTPLAINを使う

;IFを使う場合
IF RAND:3 == 0
  PRINTW 「今日はカレーが食べたい」
ELSEIF RAND:2 == 0
  PRINTW 「今日はオムライスが食べたい」
ELSE
  PRINTW 「今日はパスタが食べたい」
ENDIF

IF RAND:3 == 0
  PRINTW 「今日はカレーが食べたい」
ELSEIF RAND:3 == 1
  PRINTW 「今日はオムライスが食べたい」
ELSE
  PRINTW 「今日はパスタが食べたい」
ENDIF

SELECTCASE RAND:3
  CASE 0
    PRINTW 「今日はカレーが食べたい」
  CASE 1
    PRINTW 「今日はオムライスが食べたい」
  CASE 2
    PRINTW 「今日はパスタが食べたい」
ENDSELECT

PRINTDATAW
  DATA 「今日はカレーが食べたい」
  DATA 「今日はオムライスが食べたい」
  DATA 「今日はパスタが食べたい」
ENDDATA

DATA 「今日はチャーハンが食べたい」

SETCOLOR 255, 0, 0
PRINTW これは赤い文字です
SETCOLOR 0x00FF00
PRINTW これは緑色の文字です

SETCOLORBYNAME blue
PRINTW これは青い文字です
SETCOLORBYNAME yellow
PRINTW これは黄色い文字です

SIF COLOR_FROMNAME("yelow") == -1
  PRINTW 誤字ってます

;0番目のビットをオンにする
INT += 1
;2番目のビットをオンにする
INT += 4

;1番目のビットをオンにしたいが、オンオフの状態が分からない
SETBIT INT, 1

;0,1,2番目のビットを入れる(0111=7)
INT = 7

;0番目のビットをオフにする
INT -= 1

;2番目のビットをオフにする
INT -= 4

;1番目のビットをオフにする これはCLEARBITを使ってみる
CLEARBIT INT, 1

;0番目と2番目のビットをオンにする(0101=5)
INT = 5

IF GETBIT(INT, 0)
  PRINTW 0番目のビットはオンです
ELSE
  PRINTW 0番目のビットはオフです
ENDIF

IF GETBIT(INT, 1)
  PRINTW 1番目のビットはオンです
ELSE
  PRINTW 1番目のビットはオフです
ENDIF

IF GETBIT(INT, 2)
  PRINTW 2番目のビットはオンです
ELSE
  PRINTW 2番目のビットはオフです
ENDIF